重装系统，QB里的种子怎么备份和恢复？
如题，打算重装一下下载机的系统，但是QB里挂了600多个种子，怎么能够一次备份然后恢复到新系统去？ 下载路径保持一致的，种子文件我也有，但是要手工添加600个种子实在是太可怕了。。。[晕倒]记得以前有人问过类似问题，但是搜不到了。。。。哪位大佬再指点一下吧，谢谢了[可爱] 备份
@echo off
IF NOT EXIST "%LocalAppData%\qBittorrent" GOTO CfgNotFound
IF NOT EXIST "%AppData%\qBittorrent" GOTO CfgNotFound
ECHO 即将把qBittorrent的相关配置文件备份至“Backup"中
ECHO 若要终止备份，请按Ctrl+C键，否则按任意键开始备份
PAUSE > NUL
IF EXIST ".\Backup" (
IF EXIST ".\Backup.old" (
RD /S /Q ".\Backup.old"
)
MOVE ".\Backup" ".\Backup.old"
ECHO 上一次的备份已更名为“Backup.old”
)
XCOPY /E /I /Q "%LocalAppData%\qBittorrent" ".\Backup\Local\qBittorrent"
XCOPY /E /I /Q "%AppData%\qBittorrent" ".\Backup\Roaming\qBittorrent"
ECHO 备份完成，按任意键结束...
PAUSE > NUL
EXIT
:CfgNotFound
ECHO 没有找到qBittorrent的配置文件，无法进行备份，按任意键结束...
PAUSE > NUL
恢复
@echo off
IF NOT EXIST ".\Backup" GOTO SearchBakOld
ECHO 即将从“Backup”中恢复qBittorrent相关配置
ECHO 若要停止还原，请按Ctrl+C键，否则按任意键开始还原
PAUSE > NUL
IF EXIST "%LocalAppData%\qBittorrent" (
RD /S /Q"%LocalAppData%\qBittorrent"
)
XCOPY /E /I /Q ".\Backup\Local\qBittorrent" "%LocalAppData%\qBittorrent"
IF EXIST "%AppData%\qBittorrent" (
RD /S /Q "%AppData%\qBittorrent"
)
XCOPY /E /I /Q ".\Backup\Roaming\qBittorrent" "%AppData%\qBittorrent"
ECHO 成功从“Backup”还原配置，按任意键结束...
PAUSE > NUL
EXIT
:SearchBakOld
IF NOT EXIST ".\Backup.old" GOTO BakNotFound
ECHO 即将从“Backup.old”中恢复qBittorrent相关配置
ECHO 若要停止还原，请按Ctrl+C键，否则按任意键开始还原
PAUSE > NUL
IF EXIST "%LocalAppData%\qBittorrent" (
RD /S /Q"%LocalAppData%\qBittorrent"
)
XCOPY /E /I /Q ".\Backup.old\Local\qBittorrent" "%LocalAppData%\qBittorrent"
IF EXIST "%AppData%\qBittorrent" (
RD /S /Q "%AppData%\qBittorrent"
)
XCOPY /E /I /Q ".\Backup.old\Roaming\qBittorrent" "%AppData%\qBittorrent"
ECHO 成功从“Backup.old”还原配置，按任意键结束...
PAUSE > NUL
EXIT
:BakNotFound
ECHO 没有可以使用的备份，还原终止，按任意键结束...
PAUSE > NUL
自己建批处理，放入 qb 目录 qhdxy 发表于 2022-11-9 22:01
备份
666666666 感谢大佬指点。。。。
自己摸索了一下，差点把600个种子给搞没了。。。吓出一身冷汗[雷人]。。。还好，还好备份和恢复成功了。。再次感谢！
页:
[1]